注册 登录  
 加关注
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

云之南

风声,雨声,读书声,声声入耳;家事,国事,天下事,事事关心

 
 
 

日志

 
 
关于我

专业背景:计算机科学 研究方向与兴趣: JavaEE-Web软件开发, 生物信息学, 数据挖掘与机器学习, 智能信息系统 目前工作: 基因组, 转录组, NGS高通量数据分析, 生物数据挖掘, 植物系统发育和比较进化基因组学

网易考拉推荐

gnuplot 让您的数据可视化  

2010-08-19 22:31:11|  分类: 数理统计 |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

http://www.ibm.com/developerworks/cn/linux/l-gnuplot/index.html

http://dsec.pku.edu.cn/dsectest/dsec_cn/gnuplot/

http://www.ibm.com/developerworks/cn

http://www.gnuplot.info/
gnuplot 让您的数据可视化

自由控制高级图表和数据绘图

developerWorks
文档选项
将打印机的版面设置成横向打印模式

打印本页

将此页作为电子邮件发送

将此页作为电子邮件发送

样例代码


级别: 初级

Nishanth Sastry (nishanth_sastry@us.ibm.com), 专职软件工程师, IBM

2004 年 8 月 01 日


使用 Gnuplot 4.0 将数据和函数转换为专业的图表,Gnuplot 4.0 是一种免费分发的绘图工具。本文是 gnuplot 的实践指南,着重讲述了有效使用此工具的一些惯例。

Gnuplot 是一种免费分发的绘图工具,可以移植到各种主流平台。它可以下列两种模式之一进行操作:当需要调整和修饰图表使其正常显示时,通过在 gnuplot 提示符中发出命令,可以在交互模式下操作该工具。或者,gnuplot 可以从文件中读取命令,以批处理模式生成图表。例如,如果您正在运行一系列的实验,需要每次运行后都查看结果图表;或者当您在图表最初生成很久以后需要返回图表修改某些内容时,批处理模式能力会特别有用。当在 WYSIWIG 编辑器中很难捕获用于修饰图表的鼠标单击事件时,您可以很容易地将 gnuplot 命令保存在文件中,六个月后将其加载到交互式会话中重新执行。

Gnuplot 是在 1986 年由 Colin Kelley 和 Thomas Williams 最初开发的。许多参与者都在为不同的“终端”创建变种方面做出了贡献。在 1989 和 1990 年,这些变种被合并到 gnuplot 2.0 中。2004 年 4 月,发布了 4.0 版本。本教程将适用于 4.0 版本,但是这里介绍的大多数命令应该也适用于其他版本。在适当的地方,我将提及其中的主要区别。 参考资料中列出了 gnuplot 的官方 Web 站点。

下面,我们为初学者提供了实践指南;但是即使您以前有一些 gnuplot 的经验,您也可能会在 4.0 版本中发现新的惯例和命令。我们从简单的正弦曲线开始,将其定制为我们所希望看到的形状。然后我们将研究如何绘制一组数据点。在本文中,我们仅限于 2D 绘图,因为它们是最常见的。

GNG:Gnuplot 不是 GNU

虽然它的名称可能意味着其他方面,但 GPL 不包含 gnuplot。对于法律方面,gnuplot FAQ #1.7 指出:“从您不必为其付钱方面来讲,Gnuplot 是免费软件。不过从您不能免费分发 gnuplot 的修改版本方面来讲,它又不是免费软件。请阅读和接受发行版中的版权文件。”

初学用户时常能够很好地想出他们的图表形状,但是不知道需要使用什么 gnuplot 命令。所以了解 gnuplot 的关键是很好地掌握它的词汇表,其余应该凭足够的直觉。在本教程中,我仅能对您将在 gnuplot 中充分使用的通用选项提供一个了解;本教程并不是毫无遗漏的。所以,例如,我告诉您如何设置 x 范围来限制图表中 x 轴的范围。设置 y 范围与 x 范围相似(在命令中使用
yrange
,而不是
xrange
),但我将不再讨论。

基础

通过在 shell 命令提示符中输入
gnuplot
启动 gnuplot。您首先看到提示符号
>
。该提示符是进入 gnuplot 的输入点;Linux 用户将习惯于这种方式。例如,您可以使用方向键来查找以前输入的命令历史记录,然后编辑和重新执行这些命令;Home 和 End 键与平时使用没有区别。可以对 gnuplot 进行重新编译以便使用 GNU readline 库在输入提示符上来回移动,但类似于默认函数。

Gnuplot 提供了广泛的在线帮助,如果您要做任何有用的事情,则肯定会用到这些在线帮助。语法是统一的:通过输入
help <command>
可以获得任何命令的帮助。接着启动 gnuplot,尝试命令
help set yrange

help set
(在每个命令之后,使用
q
退出帮助)。注意
yrange

help set
下的可用子选项之一。一般来说,gnuplot 帮助为命令的所有可能定制提供进一步的帮助。浏览帮助中的示例部分通常就足可以了解如何使用命令。

Gnuplot 还有大量展示其能力的演示,通常位于安装的演示子目录中。为了获得这些能力,在 gnuplot 提示符下进入此目录中(例如,
cd '/opt/gnuplot/demo'
— 注意 gnuplot 要求所有文件名和目录名都用单引号或双引号括起来),然后输入
load 'all.dem'
。该目录中的各个 .dem 文件演示了各个函数,all.dem 将它们一次全部加载。但您可能想将此操作延迟到本文结束时进行,这样我们可以开始使用 gnuplot ,无需再进行其他操作...

对于那些想要继续的人,可以在提示符中分别输入代码清单中的每行代码。或者,将整个清单保存到一个临时文件中,然后通过在 gnuplot 提示中输入
load 'filename'
(不要忘记引号)来运行代码。

可以预见的是,2D 绘图的命令是
plot
。在提示符中输入
plot sin(x)
:您应该在弹出窗口中看到熟悉的正弦曲线。


图 1. sin(x)
图 1. sin(x)

我们刚刚创建了可能是最简单的图。让我们看看如何以不同方法定制该图。假设我们只想看到一个正弦曲线周期。我们通过限制图的默认 x 范围来完成此操作。使用表示法 [min:max] 来指定范围。要仅指定最小值,使用 [min:];要仅指定最大值,使用 [:max]。数学上称此为所谓的“闭”区间表示法。

这里我们使用 [-pi:pi] 得到一个正弦曲线周期:


清单 1. 从 -pi 到 +pi 的 sin(x)
set xrange [-pi:pi]
replot
reset

图 2. 重绘正弦曲线图
图 2. 重绘正弦曲线图

我们刚才使用了
replot
命令,它执行先前的 plot 命令。当您绘制曲线图且需要不断对该图进行修改以添加想要的特征时,此命令会非常有用。另外,replot 使您可以添加更多的图。尝试输入
replot cos(x)
。依照语法,该命令等同于
plot sin(x), cos(x)
。Replot 就是获取先前的绘图字符串,添加必要的逗号,然后附加输入给它的其余部分。

使用的最后一个命令
reset
对于绘制正弦曲线不是必要的。它移除先前所有
set
命令的效果并恢复默认值。因此,在本例中,它将使用默认 x 范围。

现在让我们尝试一些更奇特的东西:
plot sin(x)/x
。您应该看到如下所示图形:


图 3. sin(x)/x
图 3. sin(x)/x

从刚才这三个简单的例子,您可以看到 gnuplot 能够理解 pi 并具有丰富的自带数学函数词汇表。它甚至知道非常有用的管理正态分布的统计函数,以及深奥的特殊函数,如朗伯、贝塞尔、beta 和 gamma 函数(还有更多!),这些函数通常仅在 mathematica 等功能齐全的数学工具中才会有。根据经验,语法与 C 中的语法相似,C 中的语法又与平常数学中使用的语法相似。(一个重要的不同是指数的表示法:为了方便,x 的 y 次幂写为
x**y
)。

接着,将图命名为(“My First Graph”),并命名轴(x 轴是“angle, in degrees”,y 轴是“sin(angle)”)。


清单 2. 命名图和轴
set title "My first graph"
set xlabel "Angle, \n in degrees"
set ylabel "sin(angle)"
plot sin(x)

注意 xlabel 中的
\n
会产生新的一行。一般来说,gnuplot 在双引号内的字符串中进行类似于 C 的反斜杠处理。Windows 用户注意:如果您想文件名使用双引号括起来的字符串表示,则必须使用两个反斜杠:如
"c:\\developerworks"
(或者可以使用一个正斜杠:
"c:/developerworks"
)。

现在,我们注意到 x 轴实际没有标记为度数,看起来不是很好。要修改此问题,通过调整 x 轴上的 tic 标记,使指定的(主)标记仅以 90 度增加和辅标记以 45 度增加。主 tics 的“级别”为 0,这是默认值;辅 tics 的级别为 1。每个点分别由一个 3 元组指定:
"label"
(放在引号中)、
<point-at-which-tic-is-made>

<optional-level>


清单 3. 改变轴上 tic 并设置网格
set xrange [-pi:pi]                       # we want only one cycle
set xtics ("0" 0, \
"90" pi/2, "-90" -pi/2, \
"" pi/4 1, "" -pi/4 1, \
"" 3*pi/4 1, "" -3*pi/4 1)
set grid
set xlabel "Angle,\n in degrees"
set ylabel "sin(angle)"
plot sin(x)

图 4. 带有 tics、标题、网格和标签的轴的 sin(x)
图 4. 带有 tics、标题、网格和标签的轴的 sin(x)

注意对 +45 度和 -45 度辅标记使用了空标签 ("")。还要注意我们不必以任何顺序列出点。像 gnuplot 中的其他所有项一样,
xtics
命令功能非常多,具有方便的选项,用于以固定增量创建 tic 标记(在对数标度中为正常倍数),以及用于时间相关数据的特殊格式。查看
help set xtics
中的例子可以获得更多信息。

作为边注,注意我们使用反斜杠将 xtics 命令扩展成多个输入行。这样可以使比较长或比较复杂的命令更易读懂。

我们还用
set grid
来设置网格,该命令使您可以从数量上查看图。到现在为止,我们大量地使用了
set
命令。Gnuplot 有一种撤销设置的统一方法:在 gnuplot 4.0 中,命令是
unset
。例如,如果您不想要网格,使用
unset grid
。4.0 以前的版本,命令是
set nogrid

顺便说一下,我们提供的所有例子都可以在交互模式或批处理模式下运行。要以交互模式运行,在提示符中输入每个命令。要以批处理模式运行,将命令输入或添加到文本文件中,然后在 gnuplot 提示符中使用
load 'filename'
读入文件,或者在 shell 提示符下将其作为参数提供给 gnuplot:
$ gnuplot filename
。使用第二种方法,gnuplot 会在执行输入文件中的所有命令后退出,所以当直接绘图到文件中(请参见下一节)时,采用批处理模式执行特别有效。如果在屏幕上绘图时使用第二种方法,输出窗口一出现(当 gnuplot 退出时)就会消失,所以您需要使用显式的“pause -1”命令(请参阅
help pause
)来保持窗口。

批处理模式操作中使用的 Gnuplot 命令文件往往停留一会,从而帮助使用注释来提高可读性。
#
后面的直到行结束的内容是注释。所以在示例清单 3 中,gnuplot 不处理
we want only one cycle





回页首

终端设备 —— 题外话

在启动时,您可能注意到终端类型设置为
X11
。Gnuplot 采用标准设计,可以在多个终端设备上绘图。这包括直接打印到多种打印机中,包括 Epson、HP 和 Imagen 打印机。它甚至可以在伪设备中绘图,如 postscript 和 png。这主要涉及生成输出文件,而不是可查看文件或打印输出。这是将您的图表包含在其他报表中的一种技巧。虽然我还没有发现在 Windows 中与在 Linux 中有什么不同,本文档建议您在设置输出文件名之前先设置终端类型:


清单 4. 设置输出和终端类型
set terminal png         # gnuplot recommends setting terminal before output
set output "output.png" # The output filename; to be set after setting
# terminal
replot

现在,文件 output.png 中有了您刚才绘制的图,且可以包含在一个更大的报表中。许多普遍使用的排版和制图程序都有专门的终端,这些程序包括 Adobe Illustrator(
set term aifm
)、Corel Draw(
set term corel
)、AutoCad(
set term dxf
)和多种 LaTex 相关的终端(
eepic

latex

pstricks

texdraw

tpic
等等)。您还可以得到 PostScript、enhanced PostScript (eps) 或 Adobe PDF 格式的文件。您的 gnuplot 版本可能没有编译所有的终端驱动程序 —— 例如,Windows 用户不需要 Xll 终端,Linux 用户不需要 Windows 终端。类似地,出于法律原因,gnuplot 4.0 移除了对 gif 终端的支持。

所有终端在能力上都不相同。其中的一些(如 LaTeX)可能不支持文本的旋转,所以如果您像我们前面那样设置 ylabel,在不同的终端中可能显示不一样。换句话说,您可以在 LaTeX 的特定终端中使用 LaTex 命令。例如,
set ylabel "$sin(\\theta)$"
(注意我们使用两个反斜杠产生一个 LaTex 所需的反斜杠 —— gnuplot 在将双引号中所括的字符串传送到终端驱动程序之前,先对其进行反斜杠处理)。现在,您可以使用
\input{output.tex}
将输出文件包含在 LaTeX 文件中。要在 PostScript 终端中获得相同的结果,使用相应的 PostScript 命令:
{/Symbol q}
。在 enhanced PostScript 和 LaTeX 中,您可以使用表示法
x^{superscript}

x_{subscript}
得到上标文字。还要注意缩写的终端和输出命令:


清单 5. eps 驱动程序的能力
set term post enh     # enhanced PostScript, essentially PostScript
# with bounding boxes
set out 'gplt.eps'
set xlabel '{/Symbol q_1}
set ylabel 'sin^2({/Symbol q_1})'
plot sin(x)**2

参考资料部分的代码补充说明包含具有以上命令的 TeX 文件示例。

鼠标支持

版本 4.0 提供了新的功能,Windows 和 X11 终端支持鼠标交互。鼠标支持有两个主要用途:坐标跟踪和缩放。鼠标指针的当前坐标显示在终端窗口的左下角。通过双击第一个鼠标按钮可以将其复制到剪贴板中。当您需要设置需要直接坐标的标签或箭头时,此操作会非常有用。(使用
help arrow

help label
可以获得这些命令的更多详细信息。)还可以拖动第二个(或右击)鼠标按钮来选择要放大的矩形区域。在 3D 绘图中,您可以拖动鼠标来旋转图像(按住 Ctrl 键将仅更改轴的视图;所以对于要用很长时间才能呈现的图,可以先更改轴,然后放开 Ctrl 键来重新呈现图)。

鼠标支持还支持一组有用的热键:如果先前对图进行了放大, u则取消访大。 g切换网格, l切换坐标轴上的刻度; L切换最靠近指针的最标轴上的刻度, r切换标尺,标尺会建立任意原点。启用了标尺后,屏幕的底部显示当前坐标指针距离标尺原点的 x 轴距离和 y 轴距离以及距离实际原点的 x 轴和 y 轴距离(与点的坐标相同)。在 3D 中,方向键可以用在鼠标拖拉的地方来旋转图像。空格键激活命令窗口, q退出终端窗口。要查看所有选项,在支持鼠标的终端中输入 h。

控制比例和长宽比

默认情况下,gnuplot 对 x 轴和 y 轴都使用比例系数 1,但是它对控制图形的长宽比(y 轴长度与 x 轴长度的比率)不起作用。终端驱动程序使用终端的默认长宽比。比例系数、长宽比或者两者都可以使用
set size
命令指定,例如:


# square is synonymous to an aspect ratio of 1;
# scale y-axis by 2, retain x-axis size
set size ratio square 1,2

gnuplot 使用给定的长宽比能否成功绘制图可能受到终端能力的限制。
set size
也是与
multiplot
命令一起使用才有用,multiplot 命令用于在同一输出屏幕或文件中生成多个图。





回页首

绘制多条曲线

正如精明的读者可能已经从上面关于 replot 的注释中推测到的,gnuplot 使您可以同时画多条线。假设我们同时绘制正弦和余弦曲线。简单的 plot 命令为
plot sin(x), cos(x)
;要画的曲线以逗号分隔。如果不再指定其他项,gnuplot 自动显示两个曲线图,从而它们可以互相区别 —— 在诸如 Windows 和 Xll 的终端中,gnuplot 使用不同的颜色。单色终端使用不同种类的线显示曲线图。通过查看图例(或键),您应该能够知道图中的线分别是何种曲线。gnuplot 还允许您指定绘图的样式,以便获得进一步的控制:


unset xtics # keep all other things simple
plot sin(x) with linespoints pointtype 5, cos(x) w boxes lt 4
图 5. 多条曲线
图 5. 多条曲线


with
子句(请参阅
help plot with
,如果使用版本 4.0,还有
help plotting styles
)使您可以详细而精确地指定线的样式。在本例中,我们说明两种有用的样式。第一种样式
linespoints
通常在对数据绘图时非常有用,它在涉及的每个示例或数据点处标记一个点,并使用线性插值法连接连续的点。这里我们另外指定点类型为 5,它选择终端允许的第五种点。第二种样式
boxes
更适合绘制直方图数据。注意我们如何在 cos(x) 曲线中将
with
缩写成
w
。类似地,
lt
是 linetype 的缩写,是另一个特定于终端的设置,它选择终端可以绘制的四种线。不必说(什么,您还没有尝试
help plot with
吗?),您可以使用
pt
代替冗长的 pointtype。如果想在多条线中使用相同的绘图样式(在一个 plot 命令中或在多个 plot 命令中),可以使用 set 命令设置绘图样式。在 gnuplot 4.0 中,使用
set style function linespoints
;以前的版本使用语法
set function style boxes
。要更改用于绘制与函数相对的数据集合的样式,使用
set style data linespoints
(以前的版本使用
set data style linespoints
)。

gnuplot 如何工作

除了趣味性,本次练习显示了 gnuplot 实际如何对函数绘图 —— 它获取多个样本并在每个样本点绘制值。通常,它会在这些点间平滑地插入值;使用 boxes 样式则强制它使用平面的直方图,linespoints 样式用一个点标记每个样本。要更清楚地观看,显式地将采样比率设为 10(
set samples 10
)并重新绘图。(然后将其设置会默认值 100)。


with
子句是我们使用除了
set
之外的其他项来定制图的第一个例子。一些其他普遍使用的选项也可以直接在 plot 命令中设置。例如,还可以设置 xrange:
plot [-pi:pi] sin(x)
。对默认绘图选项的快速而随意的一次性更改则使用此类语法。要在多个图中或在多个 plot 命令中重新使用,需要使用
set
命令。

当绘制两条或多条曲线时,我们需要关键字或图例来对它们进行区分。默认情况下,关键字在右上角;但是如果它妨碍了图,可以将关键字放到其他位置 —— 如果愿意,甚至可以放到图外。下面的代码片段将关键字放在了左上角,并在它周围设置了一个框。我们还通过在 plot 命令中给定明确的标题来控制图例中为曲线提供的名称。title 可以缩写为 t,正如我们对余弦曲线的设置。如果不想在图例中命名曲线,使用
notitle
,而不是
title
。最后一点,也是新用户经常出错的地方就是如果有标题,标题必须放在
with
子句的前面:


清单 6. 定制图的关键字或图例
set key top left
set key box
plot [-pi:pi] sin(x) title "sinusoid" with linespoints pointtype 5, \
cos(x) t 'cosine' w boxes lt 4

图 6. 定制关键字
图 6. 定制关键字

在同一屏幕上绘制相关的图

上面,我们在同一图中绘制了正弦和余弦曲线。Gnuplot 使您还可以绘制多个图,这样它们可以并排显示在同一输出屏幕或文件中。在某些排版系统中,以一个文件的形式包含两个图形比分别包含两个图形要更容易。

下面是简单说明的
multiplot
,它绘制正弦、余弦及其各自倒数的曲线图。基本方法是将屏幕或图像文件的边框比例设为 1。然后,我们绘制不同的曲线图,从而它们可以每个图占据屏幕的四分之一。我们还通过使用屏幕坐标(请参阅
help coordinates
,获得关于不同类型坐标系统的讨论)设置原点来控制曲线图显示的位置。另外,注意每个 plot 还自动计算轴、tic 等等的宽度 —— 这样您可能必须调整边距宽度以使不同绘图的轴排成一行。在本例中,我必须将左边距设置为 6 个字符宽度,以便调整 cosec(x) = 1/sin(x) 的科学记数法中的 tics。


清单 7. Multiplot 示例
set xrange [-pi:pi]
# Uncomment the following to line up the axes
# set lmargin 6
# Gnuplot recommends setting the size and origin before going to
# multiplot mode
# This sets up bounding boxes and may be required on some terminals
set size 1,1
set origin 0,0
# Done interactively, this takes gnuplot into multiplot mode
# and brings up a new prompt ("multiplot >" instead of "gnuplot >")
set multiplot
# plot the first graph so that it takes a quarter of the screen
set size 0.5,0.5
set origin 0,0.5
plot sin(x)
# plot the second graph so that it takes a quarter of the screen
set size 0.5,0.5
set origin 0,0
plot 1/sin(x)
# plot the third graph so that it takes a quarter of the screen
set size 0.5,0.5
set origin 0.5,0.5
plot cos(x)
# plot the fourth graph so that it takes a quarter of the screen
set size 0.5,0.5
set origin 0.5,0
plot 1/cos(x)
# On some terminals, nothing gets plotted until this command is issued
unset multiplot
# remove all customization
reset

图 7. Multiplot 绘图
图 7. Multiplot 绘图



回页首

绘制数据图

虽然本教程只是出于说明目的,大部分内容都集中于绘制正弦曲线,您很可能很想对试验数据、销售数据或其他类似数据绘图。在这一节,我们将使用 IBM 的股票价格作为数据集合说明如何绘制不同的图(本例的原始数据包含在 参考资料部分中):

表 1. IBM 股票价格

日期 开盘 最高 最低 收盘
10-Jun-04 90.23 90.75 89.89 90.46
9-Jun-04 89.90 90.55 89.81 90.09
8-Jun-04 88.64 90.50 88.40 90.04
7-Jun-04 88.75 88.99 88.01 88.64
4-Jun-04 87.95 88.49 87.50 87.56
3-Jun-04 87.85 88.10 87.35 87.35
2-Jun-04 88.64 88.64 87.89 87.98
1-Jun 04 88.00 88.48 87.30 88.12

大多数数据集合都是数字列,但是这个数据集合有所不同,因为 x 轴是时间数据。下列代码告诉 gnuplot 如何读取和格式化 x 轴上的时间数据(有关详细信息,请参阅
help time/data

help set timefmt
):


清单 8. 设置时序数据
set xdata time   # The x axis data is time
set timefmt "%d-%b-%y" # The dates in the file look like 10-Jun-04
set format x "%b %d" # On the x-axis, we want tics like Jun 10

一旦设置完成,可以使用下列命令对开盘价绘图。我们选择在不同的开盘价之间使用直线插值法,并使用
linespoints
样式,而不只是
points


plot ["31-May-04":"11-Jun-04"] 'ibm.dat' using 1:2 with linespoints


图 8. 绘制开盘价图
图 8. 绘制开盘价图

象往常一样,["31-May-04":"11-Jun-04"] 显式设置了 xrange,但不是完全必要的。注意范围的
min

max
需要指定为符合
timefmt
的字符串。

取决于使用的绘图样式,gnuplot 在绘制一个点时最多可以使用六个不同的编号。当读入记录时,列从 1 开始编号。
using 1:2
告诉 plot 命令使用第一列作为 x 轴,第二列作为 y 轴。所以要绘制收盘价图,我们将使用
using 1:5

每次 gnuplot 看到新的数据分隔符时,列编号就会增加。默认情况下,数据分隔符为空格。所以如果时间格式中间有空格(例如
10 Jun 04
,而不是
10-Jun-04
),我们将需要使用
using 1:4
代替
1:2
。对于 x 轴,我们仅需要指定数据开始的第一列。Gnuplot 能够智能地使用 timefmt 字符串读取其他列。


using
使您可以添加两个以上的冒号,用于指定特定绘图样式可能需要的任何其他列。您还可以使用
$n
表示第 n 列,从而对二进制表达式进行绘图。在一个完全虚构的示例中,我们假设不同的价格表示不同的试验运行,我们要绘制平均价、最高价和最低价。
yerrorbars
样式使您可以绘制 y-high/y-low 值(我们在
using
修饰符中指定为
x:y:ylow:yhigh
)以及计算 y 轴四个价格的平均值为 ($2+$3+$4+$5)/4:


plot ["31-May-04":"11-Jun-04"] 'ibm.dat' using 1:($2+$3+$4+$5)/4:4:3 \
title 'daily prices, IBM' with yerrorbars


图 9. 计算平均值
图 9. 计算平均值

errorlines 样式是相似的,但它还在绘制的 y 轴点之间绘制线段。对于绘制财务条形图,Gnuplot 还有单独的样式,分别是最高价、最低价和 tics 在左边,右边为开盘价和收盘价。我们使用
set bars
显示开盘价和收盘价的较大 tics):


set bars 5
plot ["31-May-04":"11-Jun-04"] 'ibm.dat' using 1:2:3:4:5 with financebars


图 10. 绘制财务条形图
图 10. 绘制财务条形图

您还可以查看
help plotting styles
获得其他相关样式,如 candlesticks、boxerrorbars 和错误绘图样式。

处理真实数据集合

当然,对于真实的数据集合,事情可能会变得更复杂。最常见的就是数据集合不使用空格字符分隔数据点。gnuplot 4.0 提供了新的功能,您可以使用
set datafile separator <string>
指定自己的分隔符。同样地,您还可以使用
set datafile commentschar
指定除了
#
之外的注释字符。如果需要更多的控制,您可以为
using
修饰符明确指定格式字符串。Gnuplot 使用 C 标准库的
scanf
函数以及给定格式字符串(有关详细信息,请参阅
help using
)读入数据。我讲述此方法仅是为了内容更全面;能够以此方法读入的数据集合也可以使用
set data file separator
进行处理,或者通过显式指定
using
修饰符中要使用的列编号来进行处理。例如,如果需要忽略第一列中的字符串,则使用 2:3 进行绘图。为了获得更完全的灵活性,在具有 popen 函数的 Unix 类系统中,在将文件传送给 plot 命令之前,可以使用文本处理实用程序对文件进行预处理。例如:
plot "< awk --f preprocess.awk data.file"
。不幸的是,该命令不能在所有系统中使用。最后的一个方法是在 gnuplot 中使用输入文件之前对其进行预处理。

有时,真实的数据可能没有包含所有的点 —— 对于要绘图的列,可能有 x 值,但缺少相应的 y 值。Gnuplot 允许您指定字符串,用于表示缺少的数据点。例如:


set datafile missing 'NaN' # The IEEE floating point not-a-number

注意,在 4.0 版本之前,命令是
set missing <string>

不幸的是,处理缺少数据的数据点的方法取决于
using
说明。如果想了解用法
plot 'file'

plot 'file' using 1:2

plot 'file' using ($1):($2)
之间区别的详细信息,请参阅
help using
。但是为了安全起见,通常指定列使用显式的
using
格式,如果您想完全清除不合适的数据点,不要使用表达式求值(第三个选项会因为括号而对表达式求值)—— 而是,预处理数据文件并用计算的表达式的结果添加确切的列。

往常,您可能以一些无效的数据点而结束。如果 gnuplot 被告知忽略无效数据点,您仍可以对这样的数据集合绘图。Gnuplot 忽略未定义的点,这样当您遇到不合适的点时,技巧就是使用未定义的 y 值,如1/0。类似于 C 的三元算符可以很容易地表达此信息(如果您不熟悉此函数,请参阅
help ternary
;在定义分段函数时它也非常有用)。下面是
help using
中介绍的一个例子,它使您以第二列作为 y 值来绘图,除非第三列大于 10:


plot 'file' using 1:($3>10 ? $2 : 1/0)





回页首

高级例子

虽然本文向您展示了会经常使用的大多数命令,但可能有些地方您还需要进一步地研究。在这一节,我们简要讨论其中一些概念,然后提供了其中一个 gnuplot 演示文件(electron.dem)中的脚本,该脚本绘制电子学中常见的幅频响应图,用以说明它们的用法。


用户定义的函数和变量
您可以任意定义自己的复杂函数,如下面的 A(jw)。这些函数可以用参数 (p1, p2) 表示,您可以稍后在
plot
命令中使用它们之前再定义参数变量。
复数
Gnuplot 可以识别复数。{a,b} 表示复数 a+bi。您可以使用函数 abs() 和 arg() 获得绝对值和辐角。
虚变量
当在 plot 命令中使用 sin(x) 时,gnuplot 将 x 用作虚变量,并对它赋不同的值以获得示例。当编写复杂的用户定义的函数时,您可以使用函数定义中使用的传统变量名称,也可以显式设置要使用的虚变量的名称(例如,
set dummy jw
)。
x2 和 y2 轴
除了常见的沿着曲线图底部和左边的 x 轴和 y 轴之外,还可以使用曲线图的顶部(x2)和右端(y2)作为单独的轴。这些轴都相互独立,可以单独设置范围、tics、标签和比例(例如对数刻度)。而且,通过使用
axes
子句,
plot
命令可以使用不同的轴集合,如 x2y2。默认情况下,
plot
命令以 x 轴和 y 轴绘图。当您需要同时绘制范围为不同量级或具有不同单位的线时,此高级功能非常有帮助。在下面的示例中,y 轴绘制振幅,最大值为 1,y2 轴绘制相位,最大值为 100。如果对轴的相同集合绘图,振幅曲线几乎看不出来。
对数刻度
您可以使用
set logscale
命令以对数刻度绘制任何轴。此命令在轴上绘制以 10 为底的值的对数。您可以显式设置使用的底数(例如,
set logscale 2
,或如果仅为 x 主轴和 y 主轴设置底数,则可以使用
set logscale xy 2
)。

下例摘自与 gnuplot 一起提供的演示文件 electron.dem。此脚本使用了上面讨论的所有高级概念:


清单 9. 幅频响应
A(jw) = ({0,1}*jw/({0,1}*jw+p1)) * (1/(1+{0,1}*jw/p2))
p1 = 10
p2 = 10000
set dummy jw
set grid x y2
set key default
set logscale xy
set log x2
unset log y2
set title "Amplitude and Phase Frequency Response"
set xlabel "jw (radians)"
set xrange [1.1 : 90000.0]
set x2range [1.1 : 90000.0]
set ylabel "magnitude of A(jw)"
set y2label "Phase of A(jw) (degrees)"
set ytics nomirror
set y2tics
set tics out
set autoscale y
set autoscale y2
plot abs(A(jw)), 180/pi*arg(A(jw)) axes x2y2

图 11. 振幅和相位频率响应
图 11. 振幅和相位频率响应



回页首

结束语

在本文中,我们讨论了使用新发布的 gnuplot 4.0 绘制 2D 图形的复杂性。虽然我们接触了大多数的关于使用 gunplot 的重要方面,但限于篇幅有限,我们仍有少数主题没有讨论。值得注意的一些省略范围包括从非常简单的参数函数绘图(请参见
help parametric
)、极坐标(
help polar
),到曲线拟合(它使用户定义曲线与给定数据集合相匹配)。曲线拟合是一门艺术,需要用一整篇文章来讲述,但是请参阅
help fit
和 beginners_guide and tips 来对它获得初步了解。

常用技巧

正如我们所看到的,gnuplot 是高度可定制的。我将以这个最后的技巧来结束本文,它说明如何在多个 gnuplot 会话中重用您的定制。定制的主要命令是
set
命令。您可以使用
save set 'filename'
保存当前会话的所有设置。
save var <file>

save func <file>
分别保存用户定义的变量和函数。但是无法保存传送到单一 plot 命令的定制(例如,
plot [-pi:pi] sin(x)
中的 x 范围)。这些文件可以使用
load <file>
读回。Gnuplot 还在开始时查找名为
.gnuplot
的文件。它首先在当前目录中查找,然后在用户的主目录中查找(Windows 中的 USERPROFILE 目录)。如果找到初始化文件,gnuplot 会执行其中的命令。一些用户将此方法用于设置终端类型和定义经常使用的函数或变量。





回页首

下载

名字 大小 下载方法
source.zip 2KB HTTP
关于下载方法的信息

参考资料


您可以参阅本文在 developerWorks 全球站点上的 英文原文.
访问 gnuplot 官方站点下载最新版本
请一定注意 gnuplot 不包含在 GPL 中,也与 GNU或 Free Software Foundation 无关。 一份较老的 GNU 公告解释说:“让人奇怪的是,[gnuplot] 既不是为 GNU Project 编写,也不是因为其而命名的;这个名称纯属巧合。各种 GNU 程序都使用 gnuplot。”
实际上:gnuplot 与 GNU plotutils组合格外好用;另请参阅 plotutils documentation
官方的 Gnuplot FAQ非常有用,与非官方 not so Frequently Asked Questions 站点一样(后者有关于在科技文章中使用 gnuplot 的特定信息)。
Google search on "gnuplot introduction" 或“gnuplot 教程”提供了多篇非常有用的简短 gnuplot 3.7.x 教程,哪怕它们涉及的是以前的版本,不是最新的发行版本。
下载用于数据绘图的 IBM stock price data (ibm.dat)示例 TeX 文件 (input.tex),该示例文件说明如何将 gnuplot 绘图包含在 LaTeX 报表中。
下载本文中使用的 annotated Java code
文章“ 用 Perl/Tk 实现数据可视化”( developerWorks,2003)讨论了使用 Perl 绘图。
要大概了解如何从命令行使用 ImageMagick,请阅读“ 通过命令行处理图形”( developerWorks,2003 年 7 月)。
可伸缩向量图形介绍”( developerWorks,2004)说明了如何轻松地从数据库信息生成图形(如曲线图和图表),以及如何增加图形的生动性和交互性。
developerWorks Linux 专区中可以找到更多为 Linux 开发人员准备的资源。
在 Developer Bookstore 的 Linux 区定购 打折出售的 Linux 书籍
自 developerWorks 的 Speed-start your Linux app 专区下载可以运行于 Linux 之上的经过挑选的 developerWorks Subscription 产品免费测试版本,包括 WebSphere Studio Site Developer、WebSphere SDK for Web services、WebSphere Application Server、DB2 Universal Database Personal Developers Edition、Tivoli Access Manager 和 Lotus Domino Server。要更快速地开始上手,请参阅针对各个产品的 how-to 文章和技术支持。
  评论这张
 
阅读(2399)| 评论(0)
推荐 转载

历史上的今天

在LOFTER的更多文章

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2016